pyrox.dev
1{
2 lib,
3 buildPythonPackage,
4 fetchFromGitHub,
5 django,
6 pythonOlder,
7 setuptools,
8 docopt,
9 dj-database-url,
10 python,
11 django-filer,
12 six,
13 django-app-helper,
14}:
15
16buildPythonPackage rec {
17 pname = "django-app-helper";
18 version = "3.3.5";
19 pyproject = true;
20
21 disabled = pythonOlder "3.8";
22
23 src = fetchFromGitHub {
24 owner = "nephila";
25 repo = "django-app-helper";
26 tag = version;
27 hash = "sha256-gnTEzmQ4h4FWc2+s68VW/yVAkKFdj4U2VMkJKTAnQOM=";
28 };
29
30 build-system = [ setuptools ];
31
32 dependencies = [
33 dj-database-url
34 docopt
35 six
36 ];
37
38 checkInputs = [ django-filer ];
39
40 # Tests depend on django-filer, which depends on this package.
41 # To avoid infinite recursion, we only enable tests when building passthru.tests.
42 doCheck = false;
43
44 checkPhase = ''
45 ${python.interpreter} helper.py
46 '';
47
48 pythonImportsCheck = [ "app_helper" ];
49
50 passthru.tests = {
51 runTests = django-app-helper.overrideAttrs (_: {
52 doCheck = true;
53 });
54 };
55
56 meta = {
57 description = "Helper for Django applications development";
58 homepage = "https://django-app-helper.readthedocs.io";
59 changelog = "https://github.com/nephila/django-app-helper/releases/tag/${src.tag}";
60 license = lib.licenses.gpl2Only;
61 maintainers = [ lib.maintainers.onny ];
62 };
63}