pyrox.dev
1{
2 lib,
3 fetchDebianPatch,
4 fetchPypi,
5 buildPythonPackage,
6 m2crypto,
7 nix-update-script,
8}:
9
10buildPythonPackage rec {
11 pname = "pysimplesoap";
12 version = "1.16.2";
13 format = "setuptools";
14
15 passthru.updateScript = nix-update-script { };
16
17 src = fetchPypi {
18 pname = "PySimpleSOAP";
19 inherit version;
20 hash = "sha256-sbv00NCt/5tlIZfWGqG3ZzGtYYhJ4n0o/lyyUJFtZ+E=";
21 };
22
23 propagatedBuildInputs = [ m2crypto ];
24
25 # Patches necessary for Python 3 compatibility plus bugfixes
26 patches =
27 map
28 (
29 args:
30 fetchDebianPatch (
31 {
32 inherit pname version;
33 debianRevision = "5";
34 }
35 // args
36 )
37 )
38 [
39 # Merged upstream: f5f96210e1483f81cb5c582a6619e3ec4b473027
40 {
41 patch = "Add-quotes-to-SOAPAction-header-in-SoapClient.patch";
42 hash = "sha256-xA8Wnrpr31H8wy3zHSNfezFNjUJt1HbSXn3qUMzeKc0=";
43 }
44 # Merged upstream: ad03a21cafab982eed321553c4bfcda1755182eb
45 {
46 patch = "fix-httplib2-version-check.patch";
47 hash = "sha256-zUeF3v0N/eMyRVRH3tQLfuUfMKOD/B/aqEwFh/7HxH4=";
48 }
49 {
50 patch = "reorder-type-check-to-avoid-a-TypeError.patch";
51 hash = "sha256-2p5Cqvh0SPfJ8B38wb/xq7jWGYgpI9pavA6qkMUb6hA=";
52 }
53 # Merged upstream: 033e5899e131a2c1bdf7db5852f816f42aac9227
54 {
55 patch = "Support-integer-values-in-maxOccurs-attribute.patch";
56 hash = "sha256-IZ0DP7io+ihcnB5547cR53FAdnpRLR6z4J5KsNrkfaI=";
57 }
58 {
59 patch = "PR204.patch";
60 hash = "sha256-JlxeTnKDFxvEMFBthZsaYRbNOoBvLJhBnXCRoiL/nVw=";
61 }
62 ]
63 ++ [ ./stringIO.patch ];
64
65 meta = with lib; {
66 description = "Python simple and lightweight SOAP Library";
67 homepage = "https://github.com/pysimplesoap/pysimplesoap";
68 license = licenses.lgpl3Plus;
69
70 # I don't directly use this, only needed it as a dependency of debianbts
71 # so co-maintainers would be welcome.
72 maintainers = [ maintainers.nicoo ];
73 };
74}