Command-line and Emacs Calendar Client
ryan.freumh.org
1open Cmdliner
2open Caledonia_lib
3open Query_args
4
5let run ?from_str ?to_str ~calendar:calendars ?count ~format ~today ~tomorrow
6 ~week ~month ?timezone ~sort ~fs calendar_dir =
7 let ( let* ) = Result.bind in
8 let tz = Query_args.parse_timezone ~timezone in
9 let* from, to_ =
10 match
11 Date.convert_relative_date_formats ~tz ~today ~tomorrow ~week ~month ()
12 with
13 | Some (from, to_) ->
14 let* _ =
15 match (from_str, to_str) with
16 | None, None -> Ok ()
17 | _ ->
18 Error
19 (`Msg
20 "Can't specify --from / --to when using --today, --week, \
21 --month")
22 in
23 Ok (Some from, to_)
24 | None -> (
25 let* from =
26 match from_str with
27 | None -> Ok None
28 | Some s ->
29 let* d = Date.parse_date ~tz s `From in
30 Ok (Some d)
31 in
32 let* to_ =
33 match to_str with
34 | None -> Ok None
35 | Some s ->
36 let* d = Date.parse_date ~tz s `To in
37 Ok (Some d)
38 in
39 match (from, to_) with
40 | Some f, Some t -> Ok (Some f, Date.to_end_of_day t)
41 | Some f, None ->
42 let one_month_later = Date.add_months f 1 in
43 Ok (Some f, one_month_later)
44 | None, Some t -> Ok (None, Date.to_end_of_day t)
45 | None, None ->
46 let today_date = !Date.get_today ~tz () in
47 let one_month_later = Date.add_months today_date 1 in
48 Ok (Some today_date, one_month_later))
49 in
50 let filter =
51 match calendars with
52 | [] -> None
53 | calendar -> Some (Event.in_calendars calendar)
54 in
55 let comparator = Query_args.create_event_comparator sort in
56 let* events = Calendar_dir.get_events ~fs calendar_dir in
57 let events =
58 Event.query events ?filter ~from ~to_ ~comparator ?limit:count ()
59 in
60 if events = [] then print_endline "No events found."
61 else print_endline (Event.format_events ~format ~tz events);
62 Ok ()
63
64let cmd ~fs calendar_dir =
65 let run from_str to_str calendars count format today tomorrow week month
66 timezone sort () =
67 match
68 run ?from_str ?to_str ~calendar:calendars ?count ~format ~today ~tomorrow
69 ~week ~month ?timezone ~sort ~fs calendar_dir
70 with
71 | Error (`Msg msg) ->
72 Printf.eprintf "Error: %s\n%!" msg;
73 1
74 | Ok () -> 0
75 in
76 let term =
77 Term.(
78 const run $ from_arg $ to_arg $ calendar_arg $ count_arg $ format_arg
79 $ today_arg $ tomorrow_arg $ week_arg $ month_arg $ timezone_arg
80 $ sort_arg)
81 in
82 let doc = "List calendar events" in
83 let man =
84 [
85 `S Manpage.s_description;
86 `P
87 "List calendar events within a specified date range. By default, \
88 events from today to one month from today are shown. You can use date \
89 flags to show events for a specific time period, and filter events \
90 with the --sort option.";
91 `S Manpage.s_examples;
92 `I ("List all events for today:", "caled list --today");
93 `I ("List all events for tomorrow:", "caled list --tomorrow");
94 `I ("List all events for the current week:", "caled list --week");
95 `I ("List all events for the current month:", "caled list --month");
96 `I
97 ( "List events within a specific date range:",
98 "caled list --from 2025-03-27 --to 2025-04-01" );
99 `I ("List events from a specific calendar:", "caled list --calendar work");
100 `I ("List events in JSON format:", "caled list --format json");
101 `I ("Limit the number of events shown:", "caled list --count 5");
102 `I
103 ( "Sort by multiple fields (start time and summary):",
104 "caled list --sort start --sort summary" );
105 `I
106 ( "Sort by calendar name in descending order:",
107 "caled list --sort calendar:desc" );
108 `S Manpage.s_options;
109 ]
110 @ date_format_manpage_entries
111 @ [ `S Manpage.s_see_also ]
112 in
113 let exit_info =
114 [ Cmd.Exit.info ~doc:"on success." 0; Cmd.Exit.info ~doc:"on error." 1 ]
115 in
116 let info = Cmd.info "list" ~doc ~man ~exits:exit_info in
117 Cmd.v info term