# Aliases for DNF

# Clean package cache
[group('aliases')]
dnfc:
    sudo dnf clean all

# Install package groups
[group('aliases')]
dnfgi +groups:
    sudo dnf groupinstall {{ groups }}

# List package groups
[group('aliases')]
dnfgl:
    sudo dnf grouplist

# Remove package groups
[group('aliases')]
dnfgr +groups:
    sudo dnf groupremove {{ groups }}

# Install package(s)
[group('aliases')]
dnfi +pkgs:
    sudo dnf install {{ pkgs }}

# List packages
[group('aliases')]
dnfl:
    dnf list

# List installed packages
[group('aliases')]
dnfli:
    dnf list installed

# Make package cache
[group('aliases')]
dnfmc:
    dnf makecache

# Get info about a package
[group('aliases')]
dnfp pkg:
    dnf info {{ pkg }}

# Remove package(s)
[group('aliases')]
dnfr +pkgs:
    sudo dnf remove {{ pkgs }}

# Search packages
[group('aliases')]
dnfs pkg:
    dnf search {{ pkg }}

# Update system
[group('aliases')]
dnfu:
    sudo dnf update

# Install Fedora packages
[group('install')]
install-fedora-packages:
    #!/usr/bin/env bash
    sudo dnf copr enable -y atim/starship
    sudo dnf copr enable -y varlad/zellij
    sudo dnf install -y \
        "@c-development" \
        "@development-tools" \
        autossh \
        bat \
        borgbackup \
        borgmatic \
        butane \
        cmake \
        cmark \
        curl \
        diff-so-fancy \
        fastfetch \
        fd-find \
        ffmpeg-libs \
        fzf \
        git \
        git-core \
        glow \
        golang \
        gum \
        hugo \
        jc \
        jq \
        libuuid-devel \
        lsd \
        lynx \
        ncurses-devel \
        neovim \
        npm \
        nu \
        parallel \
        pipx \
        python3-devel \
        ripgrep \
        rsync \
        rustup \
        ShellCheck \
        shfmt \
        sl \
        starship \
        tealdeer \
        tidy \
        w3m \
        wget \
        wl-clipboard \
        xclip \
        zellij \
        zsh

# Fedora/RHEL-specific functions

# Delete selected yum repos
[group('utilities')]
delete-yum-repo:
    #!/usr/bin/env bash
    selection=$(find /etc/yum.repos.d -type f -name "*.repo" | gum choose --no-limit)
    format_string_array=("# You selected the following repo file(s):\n")
    echo "$selection" | while read -r line; do format_string_array+=("- $line\n"); done
    echo "${format_string_array[@]}" | gum format
    echo ""
    if gum confirm "Are you sure you want to delete?"; then
        sudo rm -v $(echo "$selection")
    else
        echo ":raised_eyebrow: Oh, okay then. Carry on." | gum format -t emoji
    fi

# Remove old kernels
[group('utilities')]
rm-old-kernels:
    #!/usr/bin/env bash
    old_kernels=($(dnf repoquery --installonly --latest-limit=1 -q))
    if [ "${#old_kernels[@]}" -eq 0 ]; then
        echo "No old kernels found"
        exit 0
    fi

    if ! sudo dnf remove "${old_kernels[@]}"; then
        echo "Failed to remove old kernels"
        exit 1
    fi

    echo "Successfully removed old kernels"

# vim: ts=4 sts=4 sw=4 et ft=just