[private]
default:
    @just --list

setup-zshrc:
    #!/usr/bin/env bash
    rm -fv "${HOME}/.zshrc"
    if [ "$(uname)" = "FreeBSD" ]; then
        wget https://tangled.org/strings/hyperreal.bsky.moonshadow.dev/3m7bbaryzo722/raw -O "${HOME}/.zshrc"
    else
        wget https://tangled.org/strings/hyperreal.bsky.moonshadow.dev/3m7bb7peah722/raw -O "${HOME}/.zshrc"
    fi

setup-starship:
    #!/usr/bin/env bash
    mkdir -p "${HOME}/.config"
    rm -fv "${HOME}/.config/starship.toml"
    wget https://tangled.org/strings/hyperreal.bsky.moonshadow.dev/3m7bb67wmhm22/raw -O "${HOME}/.config/starship.toml"
    if ! command -v starship; then
        curl -sS https://starship.rs/install.sh | sh
    fi

install-neovim:
    #!/usr/bin/env bash
    set -euo pipefail

    if [ ! "$(uname)" = "FreeBSD" ]; then
        # Determine cpu arch
        CPU_ARCH=$(uname -m)

        if [ "$CPU_ARCH" = "x86_64" ]; then
            NVIM_URL=$(curl --silent https://api.github.com/repos/neovim/neovim/releases/latest | jq -r '.assets[] | select(.name| test("nvim-linux-x86_64.tar.gz")).browser_download_url')
        fi

        if [ "$CPU_ARCH" = "aarch64" ]; then
            NVIM_URL=$(curl --silent https://api.github.com/repos/neovim/neovim/releases/latest | jq -r '.assets[] | select(.name| test("nvim-linux-arm64.tar.gz")).browser_download_url')
        fi

        wget "$NVIM_URL" -O /tmp/$(basename $NVIM_URL)
        tar xzvf /tmp/$(basename $NVIM_URL) -C /tmp
        sudo rsync -aAXP /tmp/$(basename -s .tar.gz $NVIM_URL)/ /usr/local
        find /tmp -maxdepth 1 -name "nvim-linux*" -exec rm -rf {} \;
    fi

clone-nvim-config:
    rm -rf "${HOME}/.config/nvim"
    rm -rf "${HOME}/.local/share/nvim"
    rm -rf "${HOME}/.local/state/nvim"
    mkdir -p "${HOME}/.config"
    git clone https://tildegit.org/hyperreal/nvim-config.git "${HOME}/.config/nvim"
    sudo rm -rf /root/.config/nvim
    sudo rm -rf /root/.local/share/nvim
    sudo rm -rf /root/.local/state/nvim
    sudo mkdir -p /root/.config
    sudo git clone https://tildegit.org/hyperreal/nvim-config.git /root/.config/nvim

# vim: ts=4 sts=4 sw=4 et ft=just