veryroundbird.house
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 lucide-src = {
15 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
16 flake = false;
17 };
18 inter-fonts-src = {
19 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
20 flake = false;
21 };
22 ibm-plex-mono-src = {
23 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
24 flake = false;
25 };
26 sqlite-lib-src = {
27 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
28 flake = false;
29 };
30 gitignore = {
31 url = "github:hercules-ci/gitignore.nix";
32 inputs.nixpkgs.follows = "nixpkgs";
33 };
34 };
35
36 outputs = {
37 self,
38 nixpkgs,
39 indigo,
40 htmx-src,
41 lucide-src,
42 gitignore,
43 inter-fonts-src,
44 sqlite-lib-src,
45 ibm-plex-mono-src,
46 }: let
47 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
48 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
49 nixpkgsFor = forAllSystems (system:
50 import nixpkgs {
51 inherit system;
52 overlays = [self.overlays.default];
53 });
54 inherit (gitignore.lib) gitignoreSource;
55 in {
56 overlays.default = final: prev: let
57 goModHash = "sha256-G+59ZwQwBbnO9ZjAB5zMEmWZbeG4k7ko/lPz+ceqYKs=";
58 appviewDeps = {
59 inherit htmx-src lucide-src inter-fonts-src ibm-plex-mono-src goModHash gitignoreSource;
60 };
61 knotDeps = {
62 inherit goModHash gitignoreSource;
63 };
64 mkPackageSet = pkgs: {
65 lexgen = pkgs.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
66 appview = pkgs.callPackage ./nix/pkgs/appview.nix appviewDeps;
67 knot = pkgs.callPackage ./nix/pkgs/knot.nix {};
68 knot-unwrapped = pkgs.callPackage ./nix/pkgs/knot-unwrapped.nix knotDeps;
69 sqlite-lib = pkgs.callPackage ./nix/pkgs/sqlite-lib.nix {
70 inherit (pkgs) gcc;
71 inherit sqlite-lib-src;
72 };
73 genjwks = pkgs.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
74 };
75 in
76 mkPackageSet final;
77
78 packages = forAllSystems (system: let
79 pkgs = nixpkgsFor.${system};
80 staticPkgs = pkgs.pkgsStatic;
81 crossPkgs = pkgs.pkgsCross.gnu64.pkgsStatic;
82 in {
83 appview = pkgs.appview;
84 lexgen = pkgs.lexgen;
85 knot = pkgs.knot;
86 knot-unwrapped = pkgs.knot-unwrapped;
87 genjwks = pkgs.genjwks;
88 sqlite-lib = pkgs.sqlite-lib;
89
90 pkgsStatic-appview = staticPkgs.appview;
91 pkgsStatic-knot = staticPkgs.knot;
92 pkgsStatic-knot-unwrapped = staticPkgs.knot-unwrapped;
93 pkgsStatic-sqlite-lib = staticPkgs.sqlite-lib;
94 pkgsCross-gnu64-pkgsStatic-appview = crossPkgs.appview;
95 pkgsCross-gnu64-pkgsStatic-knot = crossPkgs.knot;
96 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPkgs.knot-unwrapped;
97 });
98 defaultPackage = forAllSystems (system: nixpkgsFor.${system}.appview);
99 formatter = forAllSystems (system: nixpkgsFor."${system}".alejandra);
100 devShells = forAllSystems (system: let
101 pkgs = nixpkgsFor.${system};
102 staticShell = pkgs.mkShell.override {
103 stdenv = pkgs.pkgsStatic.stdenv;
104 };
105 in {
106 default = staticShell {
107 nativeBuildInputs = [
108 pkgs.go
109 pkgs.air
110 pkgs.gopls
111 pkgs.httpie
112 pkgs.lexgen
113 pkgs.litecli
114 pkgs.websocat
115 pkgs.tailwindcss
116 pkgs.nixos-shell
117 pkgs.redis
118 ];
119 shellHook = ''
120 mkdir -p appview/pages/static/{fonts,icons}
121 cp -f ${htmx-src} appview/pages/static/htmx.min.js
122 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
123 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
124 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
125 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
126 export TANGLED_OAUTH_JWKS="$(${pkgs.genjwks}/bin/genjwks)"
127 '';
128 env.CGO_ENABLED = 1;
129 };
130 });
131 apps = forAllSystems (system: let
132 pkgs = nixpkgsFor."${system}";
133 air-watcher = name: arg:
134 pkgs.writeShellScriptBin "run"
135 ''
136 ${pkgs.air}/bin/air -c /dev/null \
137 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
138 -build.bin "./out/${name}.out ${arg}" \
139 -build.stop_on_error "true" \
140 -build.include_ext "go"
141 '';
142 tailwind-watcher =
143 pkgs.writeShellScriptBin "run"
144 ''
145 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
146 '';
147 in {
148 watch-appview = {
149 type = "app";
150 program = ''${air-watcher "appview" ""}/bin/run'';
151 };
152 watch-knot = {
153 type = "app";
154 program = ''${air-watcher "knot" "server"}/bin/run'';
155 };
156 watch-tailwind = {
157 type = "app";
158 program = ''${tailwind-watcher}/bin/run'';
159 };
160 });
161
162 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
163 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
164 nixosConfigurations.knotVM = import ./nix/vm.nix {inherit self nixpkgs;};
165 };
166}