veryroundbird.house
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 indigo = {
11 url = "github:oppiliappan/indigo";
12 flake = false;
13 };
14 htmx-src = {
15 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
16 flake = false;
17 };
18 htmx-ws-src = {
19 # strange errors in consle that i can't really make out
20 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
21 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
22 flake = false;
23 };
24 lucide-src = {
25 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
26 flake = false;
27 };
28 inter-fonts-src = {
29 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
30 flake = false;
31 };
32 ibm-plex-mono-src = {
33 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
34 flake = false;
35 };
36 sqlite-lib-src = {
37 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
38 flake = false;
39 };
40 };
41
42 outputs = {
43 self,
44 nixpkgs,
45 gomod2nix,
46 indigo,
47 htmx-src,
48 htmx-ws-src,
49 lucide-src,
50 inter-fonts-src,
51 sqlite-lib-src,
52 ibm-plex-mono-src,
53 }: let
54 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
55 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
56 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
57
58 mkPackageSet = pkgs:
59 pkgs.lib.makeScope pkgs.newScope (self: {
60 src = let
61 fs = pkgs.lib.fileset;
62 in
63 fs.toSource {
64 root = ./.;
65 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
66 };
67 buildGoApplication =
68 (self.callPackage "${gomod2nix}/builder" {
69 gomod2nix = gomod2nix.legacyPackages.${pkgs.system}.gomod2nix;
70 }).buildGoApplication;
71 modules = ./nix/gomod2nix.toml;
72 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
73 inherit (pkgs) gcc;
74 inherit sqlite-lib-src;
75 };
76 genjwks = self.callPackage ./nix/pkgs/genjwks.nix {};
77 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
78 appview = self.callPackage ./nix/pkgs/appview.nix {
79 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src;
80 };
81 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
82 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
83 knot = self.callPackage ./nix/pkgs/knot.nix {};
84 });
85 in {
86 overlays.default = final: prev: {
87 inherit (mkPackageSet final) lexgen sqlite-lib genjwks spindle knot-unwrapped knot appview;
88 };
89
90 packages = forAllSystems (system: let
91 pkgs = nixpkgsFor.${system};
92 packages = mkPackageSet pkgs;
93 staticPackages = mkPackageSet pkgs.pkgsStatic;
94 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
95 in {
96 appview = packages.appview;
97 lexgen = packages.lexgen;
98 knot = packages.knot;
99 knot-unwrapped = packages.knot-unwrapped;
100 spindle = packages.spindle;
101 genjwks = packages.genjwks;
102 sqlite-lib = packages.sqlite-lib;
103
104 pkgsStatic-appview = staticPackages.appview;
105 pkgsStatic-knot = staticPackages.knot;
106 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
107 pkgsStatic-spindle = staticPackages.spindle;
108 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
109
110 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
111 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
112 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
113 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
114 });
115 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
116 formatter = forAllSystems (system: nixpkgsFor.${system}.alejandra);
117 devShells = forAllSystems (system: let
118 pkgs = nixpkgsFor.${system};
119 packages' = self.packages.${system};
120 staticShell = pkgs.mkShell.override {
121 stdenv = pkgs.pkgsStatic.stdenv;
122 };
123 in {
124 default = staticShell {
125 nativeBuildInputs = [
126 pkgs.go
127 pkgs.air
128 pkgs.gopls
129 pkgs.httpie
130 pkgs.litecli
131 pkgs.websocat
132 pkgs.tailwindcss
133 pkgs.nixos-shell
134 pkgs.redis
135 packages'.lexgen
136 ];
137 shellHook = ''
138 mkdir -p appview/pages/static/{fonts,icons}
139 cp -f ${htmx-src} appview/pages/static/htmx.min.js
140 cp -f ${htmx-ws-src} appview/pages/static/htmx-ext-ws.min.js
141 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
142 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
143 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
144 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
145 export TANGLED_OAUTH_JWKS="$(${packages'.genjwks}/bin/genjwks)"
146 '';
147 env.CGO_ENABLED = 1;
148 };
149 });
150 apps = forAllSystems (system: let
151 pkgs = nixpkgsFor."${system}";
152 air-watcher = name: arg:
153 pkgs.writeShellScriptBin "run"
154 ''
155 ${pkgs.air}/bin/air -c /dev/null \
156 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
157 -build.bin "./out/${name}.out" \
158 -build.args_bin "${arg}" \
159 -build.stop_on_error "true" \
160 -build.include_ext "go"
161 '';
162 tailwind-watcher =
163 pkgs.writeShellScriptBin "run"
164 ''
165 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
166 '';
167 in {
168 watch-appview = {
169 type = "app";
170 program = ''${air-watcher "appview" ""}/bin/run'';
171 };
172 watch-knot = {
173 type = "app";
174 program = ''${air-watcher "knot" "server"}/bin/run'';
175 };
176 watch-tailwind = {
177 type = "app";
178 program = ''${tailwind-watcher}/bin/run'';
179 };
180 vm = let
181 system =
182 if pkgs.stdenv.hostPlatform.isAarch64
183 then "aarch64"
184 else "x86_64";
185
186 nixos-shell = pkgs.nixos-shell.overrideAttrs (old: {
187 patches =
188 (old.patches or [])
189 ++ [
190 # https://github.com/Mic92/nixos-shell/pull/94
191 (pkgs.fetchpatch {
192 name = "fix-foreign-vm.patch";
193 url = "https://github.com/Mic92/nixos-shell/commit/113e4cc55ae236b5b0b1fbd8b321e9b67c77580e.patch";
194 hash = "sha256-eauetBK0wXAOcd9PYbExokNCiwz2QyFnZ4FnwGi9VCo=";
195 })
196 ];
197 });
198 in {
199 type = "app";
200 program = toString (pkgs.writeShellScript "vm" ''
201 ${nixos-shell}/bin/nixos-shell --flake .#vm-${system} --guest-system ${system}-linux
202 '');
203 };
204 gomod2nix = {
205 type = "app";
206 program = toString (pkgs.writeShellScript "gomod2nix" ''
207 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
208 '');
209 };
210 });
211
212 nixosModules.appview = {
213 lib,
214 pkgs,
215 ...
216 }: {
217 imports = [./nix/modules/appview.nix];
218
219 services.tangled-appview.package = lib.mkDefault self.packages.${pkgs.system}.appview;
220 };
221 nixosModules.knot = {
222 lib,
223 pkgs,
224 ...
225 }: {
226 imports = [./nix/modules/knot.nix];
227
228 services.tangled-knot.package = lib.mkDefault self.packages.${pkgs.system}.knot;
229 };
230 nixosModules.spindle = {
231 lib,
232 pkgs,
233 ...
234 }: {
235 imports = [./nix/modules/spindle.nix];
236
237 services.tangled-spindle.package = lib.mkDefault self.packages.${pkgs.system}.spindle;
238 };
239 nixosConfigurations.vm-x86_64 = import ./nix/vm.nix {
240 inherit self nixpkgs;
241 system = "x86_64-linux";
242 };
243 nixosConfigurations.vm-aarch64 = import ./nix/vm.nix {
244 inherit self nixpkgs;
245 system = "aarch64-linux";
246 };
247 };
248}