veryroundbird.house
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 indigo = {
11 url = "github:oppiliappan/indigo";
12 flake = false;
13 };
14 htmx-src = {
15 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
16 flake = false;
17 };
18 htmx-ws-src = {
19 # strange errors in consle that i can't really make out
20 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
21 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
22 flake = false;
23 };
24 lucide-src = {
25 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
26 flake = false;
27 };
28 inter-fonts-src = {
29 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
30 flake = false;
31 };
32 ibm-plex-mono-src = {
33 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
34 flake = false;
35 };
36 sqlite-lib-src = {
37 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
38 flake = false;
39 };
40 gitignore = {
41 url = "github:hercules-ci/gitignore.nix";
42 inputs.nixpkgs.follows = "nixpkgs";
43 };
44 };
45
46 outputs = {
47 self,
48 nixpkgs,
49 gomod2nix,
50 indigo,
51 htmx-src,
52 htmx-ws-src,
53 lucide-src,
54 gitignore,
55 inter-fonts-src,
56 sqlite-lib-src,
57 ibm-plex-mono-src,
58 }: let
59 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
60 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
61 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
62
63 mkPackageSet = pkgs:
64 pkgs.lib.makeScope pkgs.newScope (self: {
65 inherit (gitignore.lib) gitignoreSource;
66 buildGoApplication =
67 (self.callPackage "${gomod2nix}/builder" {
68 gomod2nix = gomod2nix.legacyPackages.${pkgs.system}.gomod2nix;
69 }).buildGoApplication;
70 modules = ./nix/gomod2nix.toml;
71 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
72 inherit (pkgs) gcc;
73 inherit sqlite-lib-src;
74 };
75 genjwks = self.callPackage ./nix/pkgs/genjwks.nix {};
76 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
77 appview = self.callPackage ./nix/pkgs/appview.nix {
78 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src;
79 };
80 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
81 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
82 knot = self.callPackage ./nix/pkgs/knot.nix {};
83 });
84 in {
85 overlays.default = final: prev: {
86 inherit (mkPackageSet final) lexgen sqlite-lib genjwks spindle knot-unwrapped knot appview;
87 };
88
89 packages = forAllSystems (system: let
90 pkgs = nixpkgsFor.${system};
91 packages = mkPackageSet pkgs;
92 staticPackages = mkPackageSet pkgs.pkgsStatic;
93 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
94 in {
95 appview = packages.appview;
96 lexgen = packages.lexgen;
97 knot = packages.knot;
98 knot-unwrapped = packages.knot-unwrapped;
99 spindle = packages.spindle;
100 genjwks = packages.genjwks;
101 sqlite-lib = packages.sqlite-lib;
102
103 pkgsStatic-appview = staticPackages.appview;
104 pkgsStatic-knot = staticPackages.knot;
105 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
106 pkgsStatic-spindle = staticPackages.spindle;
107 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
108
109 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
110 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
111 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
112 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
113 });
114 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
115 formatter = forAllSystems (system: nixpkgsFor.${system}.alejandra);
116 devShells = forAllSystems (system: let
117 pkgs = nixpkgsFor.${system};
118 packages' = self.packages.${system};
119 staticShell = pkgs.mkShell.override {
120 stdenv = pkgs.pkgsStatic.stdenv;
121 };
122 in {
123 default = staticShell {
124 nativeBuildInputs = [
125 pkgs.go
126 pkgs.air
127 pkgs.gopls
128 pkgs.httpie
129 pkgs.litecli
130 pkgs.websocat
131 pkgs.tailwindcss
132 pkgs.nixos-shell
133 pkgs.redis
134 packages'.lexgen
135 ];
136 shellHook = ''
137 mkdir -p appview/pages/static/{fonts,icons}
138 cp -f ${htmx-src} appview/pages/static/htmx.min.js
139 cp -f ${htmx-ws-src} appview/pages/static/htmx-ext-ws.min.js
140 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
141 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
142 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
143 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
144 export TANGLED_OAUTH_JWKS="$(${packages'.genjwks}/bin/genjwks)"
145 '';
146 env.CGO_ENABLED = 1;
147 };
148 });
149 apps = forAllSystems (system: let
150 pkgs = nixpkgsFor."${system}";
151 air-watcher = name: arg:
152 pkgs.writeShellScriptBin "run"
153 ''
154 ${pkgs.air}/bin/air -c /dev/null \
155 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
156 -build.bin "./out/${name}.out" \
157 -build.args_bin "${arg}" \
158 -build.stop_on_error "true" \
159 -build.include_ext "go"
160 '';
161 tailwind-watcher =
162 pkgs.writeShellScriptBin "run"
163 ''
164 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
165 '';
166 in {
167 watch-appview = {
168 type = "app";
169 program = ''${air-watcher "appview" ""}/bin/run'';
170 };
171 watch-knot = {
172 type = "app";
173 program = ''${air-watcher "knot" "server"}/bin/run'';
174 };
175 watch-tailwind = {
176 type = "app";
177 program = ''${tailwind-watcher}/bin/run'';
178 };
179 vm = {
180 type = "app";
181 program = toString (pkgs.writeShellScript "vm" ''
182 ${pkgs.nixos-shell}/bin/nixos-shell --flake .#vm
183 '');
184 };
185 gomod2nix = {
186 type = "app";
187 program = toString (pkgs.writeShellScript "gomod2nix" ''
188 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
189 '');
190 };
191 });
192
193 nixosModules.appview = {
194 lib,
195 pkgs,
196 ...
197 }: {
198 imports = [./nix/modules/appview.nix];
199
200 services.tangled-appview.package = lib.mkDefault self.packages.${pkgs.system}.appview;
201 };
202 nixosModules.knot = {
203 lib,
204 pkgs,
205 ...
206 }: {
207 imports = [./nix/modules/knot.nix];
208
209 services.tangled-knot.package = lib.mkDefault self.packages.${pkgs.system}.knot;
210 };
211 nixosModules.spindle = {
212 lib,
213 pkgs,
214 ...
215 }: {
216 imports = [./nix/modules/spindle.nix];
217
218 services.tangled-spindle.package = lib.mkDefault self.packages.${pkgs.system}.spindle;
219 };
220 nixosConfigurations.vm = import ./nix/vm.nix {inherit self nixpkgs;};
221 };
222}