veryroundbird.house
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 htmx-ws-src = {
15 url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
16 flake = false;
17 };
18 lucide-src = {
19 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
20 flake = false;
21 };
22 inter-fonts-src = {
23 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
24 flake = false;
25 };
26 ibm-plex-mono-src = {
27 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
28 flake = false;
29 };
30 sqlite-lib-src = {
31 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
32 flake = false;
33 };
34 gitignore = {
35 url = "github:hercules-ci/gitignore.nix";
36 inputs.nixpkgs.follows = "nixpkgs";
37 };
38 };
39
40 outputs = {
41 self,
42 nixpkgs,
43 indigo,
44 htmx-src,
45 htmx-ws-src,
46 lucide-src,
47 gitignore,
48 inter-fonts-src,
49 sqlite-lib-src,
50 ibm-plex-mono-src,
51 }: let
52 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
53 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
54 nixpkgsFor = forAllSystems (system:
55 import nixpkgs {
56 inherit system;
57 overlays = [self.overlays.default];
58 });
59 inherit (gitignore.lib) gitignoreSource;
60 in {
61 overlays.default = final: prev: let
62 goModHash = "sha256-2RUwj16RNaZ/gCOcd7b3LRCHiROCRj9HuzbBdLdgWGo=";
63 appviewDeps = {
64 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src goModHash gitignoreSource;
65 };
66 knotDeps = {
67 inherit goModHash gitignoreSource;
68 };
69 mkPackageSet = pkgs: {
70 lexgen = pkgs.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
71 appview = pkgs.callPackage ./nix/pkgs/appview.nix appviewDeps;
72 knot = pkgs.callPackage ./nix/pkgs/knot.nix {};
73 knot-unwrapped = pkgs.callPackage ./nix/pkgs/knot-unwrapped.nix knotDeps;
74 sqlite-lib = pkgs.callPackage ./nix/pkgs/sqlite-lib.nix {
75 inherit (pkgs) gcc;
76 inherit sqlite-lib-src;
77 };
78 genjwks = pkgs.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
79 };
80 in
81 mkPackageSet final;
82
83 packages = forAllSystems (system: let
84 pkgs = nixpkgsFor.${system};
85 staticPkgs = pkgs.pkgsStatic;
86 crossPkgs = pkgs.pkgsCross.gnu64.pkgsStatic;
87 in {
88 appview = pkgs.appview;
89 lexgen = pkgs.lexgen;
90 knot = pkgs.knot;
91 knot-unwrapped = pkgs.knot-unwrapped;
92 genjwks = pkgs.genjwks;
93 sqlite-lib = pkgs.sqlite-lib;
94
95 pkgsStatic-appview = staticPkgs.appview;
96 pkgsStatic-knot = staticPkgs.knot;
97 pkgsStatic-knot-unwrapped = staticPkgs.knot-unwrapped;
98 pkgsStatic-sqlite-lib = staticPkgs.sqlite-lib;
99
100 pkgsCross-gnu64-pkgsStatic-appview = crossPkgs.appview;
101 pkgsCross-gnu64-pkgsStatic-knot = crossPkgs.knot;
102 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPkgs.knot-unwrapped;
103 });
104 defaultPackage = forAllSystems (system: nixpkgsFor.${system}.appview);
105 formatter = forAllSystems (system: nixpkgsFor."${system}".alejandra);
106 devShells = forAllSystems (system: let
107 pkgs = nixpkgsFor.${system};
108 staticShell = pkgs.mkShell.override {
109 stdenv = pkgs.pkgsStatic.stdenv;
110 };
111 in {
112 default = staticShell {
113 nativeBuildInputs = [
114 pkgs.go
115 pkgs.air
116 pkgs.gopls
117 pkgs.httpie
118 pkgs.lexgen
119 pkgs.litecli
120 pkgs.websocat
121 pkgs.tailwindcss
122 pkgs.nixos-shell
123 pkgs.redis
124 ];
125 shellHook = ''
126 mkdir -p appview/pages/static/{fonts,icons}
127 ${pkgs.uglify-js}/bin/uglifyjs ${htmx-src} ${htmx-ws-src} -c -m > appview/pages/static/htmx.min.js
128 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
129 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
130 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
131 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
132 export TANGLED_OAUTH_JWKS="$(${pkgs.genjwks}/bin/genjwks)"
133 '';
134 env.CGO_ENABLED = 1;
135 };
136 });
137 apps = forAllSystems (system: let
138 pkgs = nixpkgsFor."${system}";
139 air-watcher = name: arg:
140 pkgs.writeShellScriptBin "run"
141 ''
142 ${pkgs.air}/bin/air -c /dev/null \
143 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
144 -build.bin "./out/${name}.out ${arg}" \
145 -build.stop_on_error "true" \
146 -build.include_ext "go"
147 '';
148 tailwind-watcher =
149 pkgs.writeShellScriptBin "run"
150 ''
151 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
152 '';
153 in {
154 watch-appview = {
155 type = "app";
156 program = ''${air-watcher "appview" ""}/bin/run'';
157 };
158 watch-knot = {
159 type = "app";
160 program = ''${air-watcher "knot" "server"}/bin/run'';
161 };
162 watch-tailwind = {
163 type = "app";
164 program = ''${tailwind-watcher}/bin/run'';
165 };
166 });
167
168 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
169 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
170 nixosConfigurations.knotVM = import ./nix/vm.nix {inherit self nixpkgs;};
171 };
172}