veryroundbird.house
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 gomod2nix = {
7 url = "github:nix-community/gomod2nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 indigo = {
11 url = "github:oppiliappan/indigo";
12 flake = false;
13 };
14 htmx-src = {
15 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
16 flake = false;
17 };
18 htmx-ws-src = {
19 # strange errors in consle that i can't really make out
20 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
21 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
22 flake = false;
23 };
24 lucide-src = {
25 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
26 flake = false;
27 };
28 inter-fonts-src = {
29 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
30 flake = false;
31 };
32 ibm-plex-mono-src = {
33 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
34 flake = false;
35 };
36 sqlite-lib-src = {
37 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
38 flake = false;
39 };
40 };
41
42 outputs = {
43 self,
44 nixpkgs,
45 gomod2nix,
46 indigo,
47 htmx-src,
48 htmx-ws-src,
49 lucide-src,
50 inter-fonts-src,
51 sqlite-lib-src,
52 ibm-plex-mono-src,
53 }: let
54 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
55 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
56 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
57
58 mkPackageSet = pkgs:
59 pkgs.lib.makeScope pkgs.newScope (self: {
60 src = let
61 fs = pkgs.lib.fileset;
62 in
63 fs.toSource {
64 root = ./.;
65 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
66 };
67 buildGoApplication =
68 (self.callPackage "${gomod2nix}/builder" {
69 gomod2nix = gomod2nix.legacyPackages.${pkgs.system}.gomod2nix;
70 }).buildGoApplication;
71 modules = ./nix/gomod2nix.toml;
72 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
73 inherit (pkgs) gcc;
74 inherit sqlite-lib-src;
75 };
76 genjwks = self.callPackage ./nix/pkgs/genjwks.nix {};
77 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
78 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
79 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src;
80 };
81 appview = self.callPackage ./nix/pkgs/appview.nix {};
82 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
83 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
84 knot = self.callPackage ./nix/pkgs/knot.nix {};
85 });
86 in {
87 overlays.default = final: prev: {
88 inherit (mkPackageSet final) lexgen sqlite-lib genjwks spindle knot-unwrapped knot appview;
89 };
90
91 packages = forAllSystems (system: let
92 pkgs = nixpkgsFor.${system};
93 packages = mkPackageSet pkgs;
94 staticPackages = mkPackageSet pkgs.pkgsStatic;
95 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
96 in {
97 inherit (packages) appview appview-static-files lexgen genjwks spindle knot knot-unwrapped sqlite-lib;
98
99 pkgsStatic-appview = staticPackages.appview;
100 pkgsStatic-knot = staticPackages.knot;
101 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
102 pkgsStatic-spindle = staticPackages.spindle;
103 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
104
105 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
106 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
107 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
108 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
109 });
110 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
111 formatter = forAllSystems (system: nixpkgsFor.${system}.alejandra);
112 devShells = forAllSystems (system: let
113 pkgs = nixpkgsFor.${system};
114 packages' = self.packages.${system};
115 staticShell = pkgs.mkShell.override {
116 stdenv = pkgs.pkgsStatic.stdenv;
117 };
118 in {
119 default = staticShell {
120 nativeBuildInputs = [
121 pkgs.go
122 pkgs.air
123 pkgs.gopls
124 pkgs.httpie
125 pkgs.litecli
126 pkgs.websocat
127 pkgs.tailwindcss
128 pkgs.nixos-shell
129 pkgs.redis
130 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
131 packages'.lexgen
132 ];
133 shellHook = ''
134 mkdir -p appview/pages/static
135 # no preserve is needed because watch-tailwind will want to be able to overwrite
136 cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
137 export TANGLED_OAUTH_JWKS="$(${packages'.genjwks}/bin/genjwks)"
138 '';
139 env.CGO_ENABLED = 1;
140 };
141 });
142 apps = forAllSystems (system: let
143 pkgs = nixpkgsFor."${system}";
144 packages' = self.packages.${system};
145 air-watcher = name: arg:
146 pkgs.writeShellScriptBin "run"
147 ''
148 ${pkgs.air}/bin/air -c /dev/null \
149 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
150 -build.bin "./out/${name}.out" \
151 -build.args_bin "${arg}" \
152 -build.stop_on_error "true" \
153 -build.include_ext "go"
154 '';
155 tailwind-watcher =
156 pkgs.writeShellScriptBin "run"
157 ''
158 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
159 '';
160 in {
161 watch-appview = {
162 type = "app";
163 program = toString (pkgs.writeShellScript "watch-appview" ''
164 echo "copying static files to appview/pages/static..."
165 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
166 ${air-watcher "appview" ""}/bin/run
167 '');
168 };
169 watch-knot = {
170 type = "app";
171 program = ''${air-watcher "knot" "server"}/bin/run'';
172 };
173 watch-tailwind = {
174 type = "app";
175 program = ''${tailwind-watcher}/bin/run'';
176 };
177 vm = let
178 guestSystem =
179 if pkgs.stdenv.hostPlatform.isAarch64
180 then "aarch64-linux"
181 else "x86_64-linux";
182 in {
183 type = "app";
184 program =
185 (pkgs.writeShellApplication {
186 name = "launch-vm";
187 text = ''
188 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
189 cd "$rootDir"
190
191 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
192
193 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
194 exec ${pkgs.lib.getExe
195 (import ./nix/vm.nix {
196 inherit nixpkgs self;
197 system = guestSystem;
198 hostSystem = system;
199 }).config.system.build.vm}
200 '';
201 })
202 + /bin/launch-vm;
203 };
204 gomod2nix = {
205 type = "app";
206 program = toString (pkgs.writeShellScript "gomod2nix" ''
207 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
208 '');
209 };
210 lexgen = {
211 type = "app";
212 program =
213 (pkgs.writeShellApplication {
214 name = "lexgen";
215 text = ''
216 if ! command -v lexgen > /dev/null; then
217 echo "error: must be executed from devshell"
218 exit 1
219 fi
220
221 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
222 cd "$rootDir"
223
224 rm api/tangled/*
225 lexgen --build-file lexicon-build-config.json lexicons
226 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
227 ${pkgs.gotools}/bin/goimports -w api/tangled/*
228 go run cmd/gen.go
229 lexgen --build-file lexicon-build-config.json lexicons
230 rm api/tangled/*.bak
231 '';
232 })
233 + /bin/lexgen;
234 };
235 });
236
237 nixosModules.appview = {
238 lib,
239 pkgs,
240 ...
241 }: {
242 imports = [./nix/modules/appview.nix];
243
244 services.tangled-appview.package = lib.mkDefault self.packages.${pkgs.system}.appview;
245 };
246 nixosModules.knot = {
247 lib,
248 pkgs,
249 ...
250 }: {
251 imports = [./nix/modules/knot.nix];
252
253 services.tangled-knot.package = lib.mkDefault self.packages.${pkgs.system}.knot;
254 };
255 nixosModules.spindle = {
256 lib,
257 pkgs,
258 ...
259 }: {
260 imports = [./nix/modules/spindle.nix];
261
262 services.tangled-spindle.package = lib.mkDefault self.packages.${pkgs.system}.spindle;
263 };
264 };
265}