veryroundbird.house
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 htmx-ws-src = {
15 # strange errors in consle that i can't really make out
16 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
17 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
18 flake = false;
19 };
20 lucide-src = {
21 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
22 flake = false;
23 };
24 inter-fonts-src = {
25 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
26 flake = false;
27 };
28 ibm-plex-mono-src = {
29 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
30 flake = false;
31 };
32 sqlite-lib-src = {
33 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
34 flake = false;
35 };
36 gitignore = {
37 url = "github:hercules-ci/gitignore.nix";
38 inputs.nixpkgs.follows = "nixpkgs";
39 };
40 };
41
42 outputs = {
43 self,
44 nixpkgs,
45 indigo,
46 htmx-src,
47 htmx-ws-src,
48 lucide-src,
49 gitignore,
50 inter-fonts-src,
51 sqlite-lib-src,
52 ibm-plex-mono-src,
53 }: let
54 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
55 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
56 nixpkgsFor = forAllSystems (system:
57 import nixpkgs {
58 inherit system;
59 overlays = [self.overlays.default];
60 });
61 inherit (gitignore.lib) gitignoreSource;
62 in {
63 overlays.default = final: prev: let
64 goModHash = "sha256-2RUwj16RNaZ/gCOcd7b3LRCHiROCRj9HuzbBdLdgWGo=";
65 appviewDeps = {
66 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src goModHash gitignoreSource;
67 };
68 knotDeps = {
69 inherit goModHash gitignoreSource;
70 };
71 spindleDeps = {
72 inherit goModHash gitignoreSource;
73 };
74 mkPackageSet = pkgs: {
75 lexgen = pkgs.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
76 appview = pkgs.callPackage ./nix/pkgs/appview.nix appviewDeps;
77 knot = pkgs.callPackage ./nix/pkgs/knot.nix {};
78 spindle = pkgs.callPackage ./nix/pkgs/spindle.nix spindleDeps;
79 knot-unwrapped = pkgs.callPackage ./nix/pkgs/knot-unwrapped.nix knotDeps;
80 sqlite-lib = pkgs.callPackage ./nix/pkgs/sqlite-lib.nix {
81 inherit (pkgs) gcc;
82 inherit sqlite-lib-src;
83 };
84 genjwks = pkgs.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
85 };
86 in
87 mkPackageSet final;
88
89 packages = forAllSystems (system: let
90 pkgs = nixpkgsFor.${system};
91 staticPkgs = pkgs.pkgsStatic;
92 crossPkgs = pkgs.pkgsCross.gnu64.pkgsStatic;
93 in {
94 appview = pkgs.appview;
95 lexgen = pkgs.lexgen;
96 knot = pkgs.knot;
97 knot-unwrapped = pkgs.knot-unwrapped;
98 spindle = pkgs.spindle;
99 genjwks = pkgs.genjwks;
100 sqlite-lib = pkgs.sqlite-lib;
101
102 pkgsStatic-appview = staticPkgs.appview;
103 pkgsStatic-knot = staticPkgs.knot;
104 pkgsStatic-knot-unwrapped = staticPkgs.knot-unwrapped;
105 pkgsStatic-spindle = staticPkgs.spindle;
106 pkgsStatic-sqlite-lib = staticPkgs.sqlite-lib;
107
108 pkgsCross-gnu64-pkgsStatic-appview = crossPkgs.appview;
109 pkgsCross-gnu64-pkgsStatic-knot = crossPkgs.knot;
110 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPkgs.knot-unwrapped;
111 pkgsCross-gnu64-pkgsStatic-spindle = crossPkgs.spindle;
112 });
113 defaultPackage = forAllSystems (system: nixpkgsFor.${system}.appview);
114 formatter = forAllSystems (system: nixpkgsFor."${system}".alejandra);
115 devShells = forAllSystems (system: let
116 pkgs = nixpkgsFor.${system};
117 staticShell = pkgs.mkShell.override {
118 stdenv = pkgs.pkgsStatic.stdenv;
119 };
120 in {
121 default = staticShell {
122 nativeBuildInputs = [
123 pkgs.go
124 pkgs.air
125 pkgs.gopls
126 pkgs.httpie
127 pkgs.lexgen
128 pkgs.litecli
129 pkgs.websocat
130 pkgs.tailwindcss
131 pkgs.nixos-shell
132 pkgs.redis
133 ];
134 shellHook = ''
135 mkdir -p appview/pages/static/{fonts,icons}
136 ${pkgs.uglify-js}/bin/uglifyjs ${htmx-src} ${htmx-ws-src} -c -m > appview/pages/static/htmx.min.js
137 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
138 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
139 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
140 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
141 export TANGLED_OAUTH_JWKS="$(${pkgs.genjwks}/bin/genjwks)"
142 '';
143 env.CGO_ENABLED = 1;
144 };
145 });
146 apps = forAllSystems (system: let
147 pkgs = nixpkgsFor."${system}";
148 air-watcher = name: arg:
149 pkgs.writeShellScriptBin "run"
150 ''
151 ${pkgs.air}/bin/air -c /dev/null \
152 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
153 -build.bin "./out/${name}.out ${arg}" \
154 -build.stop_on_error "true" \
155 -build.include_ext "go"
156 '';
157 tailwind-watcher =
158 pkgs.writeShellScriptBin "run"
159 ''
160 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
161 '';
162 in {
163 watch-appview = {
164 type = "app";
165 program = ''${air-watcher "appview" ""}/bin/run'';
166 };
167 watch-knot = {
168 type = "app";
169 program = ''${air-watcher "knot" "server"}/bin/run'';
170 };
171 watch-tailwind = {
172 type = "app";
173 program = ''${tailwind-watcher}/bin/run'';
174 };
175 });
176
177 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
178 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
179 nixosModules.spindle = import ./nix/modules/spindle.nix {inherit self;};
180 nixosConfigurations.vm = import ./nix/vm.nix {inherit self nixpkgs;};
181 };
182}