veryroundbird.house
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 lucide-src = {
15 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
16 flake = false;
17 };
18 inter-fonts-src = {
19 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
20 flake = false;
21 };
22 ibm-plex-mono-src = {
23 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
24 flake = false;
25 };
26 sqlite-lib-src = {
27 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
28 flake = false;
29 };
30 gitignore = {
31 url = "github:hercules-ci/gitignore.nix";
32 inputs.nixpkgs.follows = "nixpkgs";
33 };
34 };
35
36 outputs = {
37 self,
38 nixpkgs,
39 indigo,
40 htmx-src,
41 lucide-src,
42 gitignore,
43 inter-fonts-src,
44 sqlite-lib-src,
45 ibm-plex-mono-src,
46 }: let
47 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
48 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
49 nixpkgsFor = forAllSystems (system:
50 import nixpkgs {
51 inherit system;
52 overlays = [self.overlays.default];
53 });
54 inherit (gitignore.lib) gitignoreSource;
55 in {
56 overlays.default = final: prev: let
57 goModHash = "sha256-+OQfLBXd5OQuITHRPaxXQs49vPGfQfsNJzpcjJjeHKs=";
58 appviewDeps = {
59 inherit htmx-src lucide-src inter-fonts-src ibm-plex-mono-src goModHash gitignoreSource;
60 };
61 knotDeps = {
62 inherit goModHash gitignoreSource;
63 };
64 mkPackageSet = pkgs: {
65 lexgen = pkgs.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
66 appview = pkgs.callPackage ./nix/pkgs/appview.nix appviewDeps;
67 # appview-static = final.pkgsStatic.callPackage ./nix/pkgs/appview.nix appviewDeps;
68 # appview-cross = final.pkgsCross.gnu64.pkgsStatic.callPackage ./nix/pkgs/appview.nix appviewDeps;
69 knot = pkgs.callPackage ./nix/pkgs/knot.nix {};
70 # knot-static = final.pkgsStatic.callPackage ./nix/pkgs/knot.nix {};
71 knot-unwrapped = pkgs.callPackage ./nix/pkgs/knot-unwrapped.nix knotDeps;
72 # knot-unwrapped-static = final.pkgsStatic.callPackage ./nix/pkgs/knot-unwrapped.nix knotDeps;
73 # knot-cross = final.pkgsCross.gnu64.pkgsStatic.callPackage ./nix/pkgs/knot.nix knotDeps;
74 sqlite-lib = pkgs.callPackage ./nix/pkgs/sqlite-lib.nix {
75 inherit (pkgs) gcc;
76 inherit sqlite-lib-src;
77 };
78 genjwks = pkgs.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
79 };
80 in mkPackageSet final;
81
82 packages = forAllSystems (system: let
83 pkgs = nixpkgsFor.${system};
84 staticPkgs = pkgs.pkgsStatic;
85 crossPkgs = pkgs.pkgsCross.gnu64.pkgsStatic;
86 in {
87 appview = pkgs.appview;
88 lexgen = pkgs.lexgen;
89 knot = pkgs.knot;
90 knot-unwrapped = pkgs.knot-unwrapped;
91 genjwks = pkgs.genjwks;
92 sqlite-lib = pkgs.sqlite-lib;
93
94 pkgsStatic-appview = staticPkgs.appview;
95 pkgsStatic-knot = staticPkgs.knot;
96 pkgsStatic-knot-unwrapped = staticPkgs.knot-unwrapped;
97 pkgsStatic-sqlite-lib = staticPkgs.sqlite-lib;
98
99 pkgsCross-gnu64-pkgsStatic-appview = crossPkgs.appview;
100 pkgsCross-gnu64-pkgsStatic-knot = crossPkgs.knot;
101 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPkgs.knot-unwrapped;
102 });
103 defaultPackage = forAllSystems (system: nixpkgsFor.${system}.appview);
104 formatter = forAllSystems (system: nixpkgsFor."${system}".alejandra);
105 devShells = forAllSystems (system: let
106 pkgs = nixpkgsFor.${system};
107 staticShell = pkgs.mkShell.override {
108 stdenv = pkgs.pkgsStatic.stdenv;
109 };
110 in {
111 default = staticShell {
112 nativeBuildInputs = [
113 pkgs.go
114 pkgs.air
115 pkgs.gopls
116 pkgs.httpie
117 pkgs.lexgen
118 pkgs.litecli
119 pkgs.websocat
120 pkgs.tailwindcss
121 pkgs.nixos-shell
122 pkgs.redis
123 ];
124 shellHook = ''
125 mkdir -p appview/pages/static/{fonts,icons}
126 cp -f ${htmx-src} appview/pages/static/htmx.min.js
127 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
128 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
129 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
130 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
131 export TANGLED_OAUTH_JWKS="$(${pkgs.genjwks}/bin/genjwks)"
132 '';
133 env.CGO_ENABLED = 1;
134 };
135 });
136 apps = forAllSystems (system: let
137 pkgs = nixpkgsFor."${system}";
138 air-watcher = name: arg:
139 pkgs.writeShellScriptBin "run"
140 ''
141 ${pkgs.air}/bin/air -c /dev/null \
142 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
143 -build.bin "./out/${name}.out ${arg}" \
144 -build.stop_on_error "true" \
145 -build.include_ext "go"
146 '';
147 tailwind-watcher =
148 pkgs.writeShellScriptBin "run"
149 ''
150 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
151 '';
152 in {
153 watch-appview = {
154 type = "app";
155 program = ''${air-watcher "appview" ""}/bin/run'';
156 };
157 watch-knot = {
158 type = "app";
159 program = ''${air-watcher "knot" "server"}/bin/run'';
160 };
161 watch-tailwind = {
162 type = "app";
163 program = ''${tailwind-watcher}/bin/run'';
164 };
165 });
166
167 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
168 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
169 nixosConfigurations.knotVM = import ./nix/vm.nix {inherit self nixpkgs;};
170 };
171}