veryroundbird.house
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 lucide-src = {
15 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
16 flake = false;
17 };
18 inter-fonts-src = {
19 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
20 flake = false;
21 };
22 ibm-plex-mono-src = {
23 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
24 flake = false;
25 };
26 sqlite-lib-src = {
27 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
28 flake = false;
29 };
30 gitignore = {
31 url = "github:hercules-ci/gitignore.nix";
32 inputs.nixpkgs.follows = "nixpkgs";
33 };
34 };
35
36 outputs = {
37 self,
38 nixpkgs,
39 indigo,
40 htmx-src,
41 lucide-src,
42 gitignore,
43 inter-fonts-src,
44 sqlite-lib-src,
45 ibm-plex-mono-src,
46 }: let
47 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
48 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
49 nixpkgsFor = forAllSystems (system:
50 import nixpkgs {
51 inherit system;
52 overlays = [self.overlays.default];
53 });
54 inherit (gitignore.lib) gitignoreSource;
55 in {
56 overlays.default = final: prev: let
57 goModHash = "sha256-QPyeKKr7YMblwicQNemu3OamXwg7fVie6/IY10vQCl4=";
58 appviewDeps = {
59 inherit htmx-src lucide-src inter-fonts-src ibm-plex-mono-src goModHash gitignoreSource;
60 };
61 knotDeps = {
62 inherit goModHash gitignoreSource;
63 };
64 in {
65 lexgen = final.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
66 appview = final.pkgsStatic.callPackage ./nix/pkgs/appview.nix appviewDeps;
67 appview-cross = final.pkgsCross.gnu64.pkgsStatic.callPackage ./nix/pkgs/appview.nix appviewDeps;
68 knot = final.pkgsStatic.callPackage ./nix/pkgs/knot.nix {};
69 knot-unwrapped = final.pkgsStatic.callPackage ./nix/pkgs/knot-unwrapped.nix knotDeps;
70 knot-cross = final.pkgsCross.gnu64.pkgsStatic.callPackage ./nix/pkgs/knot.nix knotDeps;
71 sqlite-lib = final.pkgsStatic.callPackage ./nix/pkgs/sqlite-lib.nix {
72 inherit (final.pkgsStatic) gcc;
73 inherit sqlite-lib-src;
74 };
75 genjwks = final.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
76 };
77
78 packages = forAllSystems (system: {
79 inherit
80 (nixpkgsFor."${system}")
81 lexgen
82 appview
83 appview-cross
84 knot
85 knot-cross
86 knot-unwrapped
87 genjwks
88 sqlite-lib
89 ;
90 });
91 defaultPackage = forAllSystems (system: nixpkgsFor.${system}.appview);
92 formatter = forAllSystems (system: nixpkgsFor."${system}".alejandra);
93 devShells = forAllSystems (system: let
94 pkgs = nixpkgsFor.${system};
95 staticShell = pkgs.mkShell.override {
96 stdenv = pkgs.pkgsStatic.stdenv;
97 };
98 in {
99 default = staticShell {
100 nativeBuildInputs = [
101 pkgs.go
102 pkgs.air
103 pkgs.gopls
104 pkgs.httpie
105 pkgs.lexgen
106 pkgs.litecli
107 pkgs.websocat
108 pkgs.tailwindcss
109 pkgs.nixos-shell
110 pkgs.redis
111 ];
112 shellHook = ''
113 mkdir -p appview/pages/static/{fonts,icons}
114 cp -f ${htmx-src} appview/pages/static/htmx.min.js
115 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
116 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
117 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
118 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
119 export TANGLED_OAUTH_JWKS="$(${pkgs.genjwks}/bin/genjwks)"
120 '';
121 env.CGO_ENABLED = 1;
122 };
123 });
124 apps = forAllSystems (system: let
125 pkgs = nixpkgsFor."${system}";
126 air-watcher = name: arg:
127 pkgs.writeShellScriptBin "run"
128 ''
129 ${pkgs.air}/bin/air -c /dev/null \
130 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
131 -build.bin "./out/${name}.out ${arg}" \
132 -build.stop_on_error "true" \
133 -build.include_ext "go"
134 '';
135 tailwind-watcher =
136 pkgs.writeShellScriptBin "run"
137 ''
138 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
139 '';
140 in {
141 watch-appview = {
142 type = "app";
143 program = ''${air-watcher "appview" ""}/bin/run'';
144 };
145 watch-knot = {
146 type = "app";
147 program = ''${air-watcher "knot" "server"}/bin/run'';
148 };
149 watch-tailwind = {
150 type = "app";
151 program = ''${tailwind-watcher}/bin/run'';
152 };
153 });
154
155 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
156 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
157 nixosConfigurations.knotVM = import ./nix/vm.nix {inherit self nixpkgs;};
158 };
159}