{
  lib,
  pkgs,
  roc-lang,
  yemou-scripts,
  ...
}:
{
  nixpkgs.overlays = [
    yemou-scripts.overlays.default
    (final: prev: {
      nautilus = prev.nautilus.overrideAttrs (
        finalAttrs: prevAttrs: {
          postInstall = (prevAttrs.postInstall or "") + ''
            mkdir -p $out/share/xdg-desktop-portal/portals
            cat > $out/share/xdg-desktop-portal/portals/nautilus.portal <<EOF
            [portal]
            DBusName=org.gnome.Nautilus
            Interfaces=org.freedesktop.impl.portal.FileChooser
            EOF
          '';
        }
      );
      roc = roc-lang.packages.${prev.system}.default;
      roc-lang-server = roc-lang.packages.${prev.system}.lang-server;
      xdg-desktop-portal-wlr = prev.xdg-desktop-portal-wlr.overrideAttrs (
        finalAttrs: prevAttrs: {
          version = "0.7.1";

          src = prev.fetchFromGitHub {
            owner = "emersion";
            repo = "xdg-desktop-portal-wlr";
            rev = "v${finalAttrs.version}";
            sha256 = "sha256-GIIDeZMIGUiZV0IUhcclRVThE5LKaqVc5VwnNT8beNU=";
          };
        }
      );
    })
  ];

  # TODO: Create wrapper scripts to better manage the graphical-session-pre and graphical-session systemd targets
  # TODO: Make river execute the init.roc file I have instead of just init
  # TODO: switch to river when 0.4.0 releases
  programs.river-classic = {
    enable = true;
    package = pkgs.river-classic.overrideAttrs (
      final: prev: {
        postInstall = ''
          echo 'DesktopNames=river;wlroots' >> contrib/river.desktop
          ${prev.postInstall}
        '';
      }
    );
    # TODO: Move organize these some how
    extraPackages = with pkgs; [
      bemenu
      chayang
      ffmpegthumbnailer
      kanshi
      lswt
      mako
      nautilus
      roc
      roc-lang-server
      scr
      slurp
      swaybg
      swayidle
      swaylock
      wlopm
      wlsunset
      xrandr # Needed to set xwayland primary output
    ];
  };

  # TODO: make a script that will start river using these targets properly
  # Will need a Desktop Entry, the script will first call call `river-session-pre` and then once river is started,
  # `river-session` will be called from inside river. When river terminates, both `river-session` and
  # `river-session-pre` will be un called
  systemd.user.targets = {
    "river-session-pre" = {
      description = "River compositor session";
      bindsTo = [ "graphical-session-pre.target" ];
    };
    "river-session" = {
      description = "River compositor session";
      bindsTo = [ "graphical-session.target" ];
      wants = [ "graphical-session-pre.target" ];
      after = [ "graphical-session-pre.target" ];
    };
  };

  xdg.portal = {
    wlr = {
      enable = true;
      settings.screencast.max_fps = 60;
    };
    extraPortals = with pkgs; [ xdg-desktop-portal-gtk ];
    config.river = {
      default = lib.mkForce "gtk";
      "org.freedesktop.impl.portal.FileChooser" = "nautilus";
      "org.freedesktop.impl.portal.Inhibit" = "none";
      "org.freedesktop.impl.portal.ScreenCast" = "wlr";
      "org.freedesktop.impl.portal.Screenshot" = "wlr";
    };
  };
}